' Kod ponownie definiuje okrelon relacj zaufania
' ------ KONFIGURACJA SKRYPTU ------
' Okrelenie nazwy DNS lub NetBIOS domeny systemu Windows 2000 lub Windows NT
' bd obszaru Kerberos, ktrego relacja zaufania ma zosta ponownie zdefiniowana.
strTrustName = "<RelacjaZaufaniaDoSprawdzenia>"

' Zdefiniowanie nazwy DNS domeny rdowej lub ufajcej.
strDomain    = "<DomenaUfajca>"
' ------ KONIEC KONFIGURACJI ---------

' Uaktywnienie SC_RESET podczas wyliczania relacji zaufania.
set objTrustProv = GetObject("winmgmts:\\" & strDomain & _
              "\root\MicrosoftActiveDirectory:Microsoft_TrustProvider=@")
objTrustProv.TrustCheckLevel = 3  ' Wyliczanie z uyciem SC_RESET
objTrustProv.Put_

' Sprawdzanie relacji zaufania i zwracanie informacji dotyczcych statusu.
set objWMI = GetObject("winmgmts:\\" & strDomain & _
                       "\root\MicrosoftActiveDirectory")
set objTrusts = objWMI.ExecQuery("Select * " _
                        & " from Microsoft_DomainTrustStatus " _
                        & " where TrustedDomain = '" & strTrustName & "'" )
for each objTrust in objTrusts
    Wscript.Echo objTrust.TrustedDomain
    Wscript.Echo " TrustedAttributes: " & objTrust.TrustAttributes
    Wscript.Echo " TrustedDCName: "     & objTrust.TrustedDCName
    Wscript.Echo " TrustedDirection: "  & objTrust.TrustDirection
    Wscript.Echo " TrustIsOk: "         & objTrust.TrustIsOK
    Wscript.Echo " TrustStatus: "       & objTrust.TrustStatus
    Wscript.Echo " TrustStatusString: " & objTrust.TrustStatusString
    Wscript.Echo " TrustType: "         & objTrust.TrustType
    Wscript.Echo ""
next
