' Kod generuje list posiadaczy roli FSMO w okrelonej domenie
' ------ KONFIGURACJA SKRYPTU ------
strDomain = "<NazwaDNSDomeny>"  ' np. emea.rallencorp.com
' ------ KONIEC KONFIGURACJI ---------

set objRootDSE = GetObject("LDAP://" & strDomain & "/RootDSE")
strDomainDN  = objRootDSE.Get("defaultNamingContext")
strSchemaDN = objRootDSE.Get("schemaNamingContext")
strConfigDN = objRootDSE.Get("configurationNamingContext")

' Emulator PDC
set objPDCFsmo = GetObject("LDAP://" & strDomainDN)
Wscript.Echo "Emulator PDC: " & objPDCFsmo.fsmoroleowner

' Wzorzec RID
set objRIDFsmo = GetObject("LDAP://cn=RID Manager$,cn=system," & strDomainDN)
Wscript.Echo "Wzorzec RID: " & objRIDFsmo.fsmoroleowner

' Wzorzec schematu
set objSchemaFsmo = GetObject("LDAP://" & strSchemaDN)
Wscript.Echo "Wzorzec schematu: " & objSchemaFsmo.fsmoroleowner

' Wzorzec infrastruktury
set objInfraFsmo = GetObject("LDAP://cn=Infrastructure," & strDomainDN)
Wscript.Echo "Wzorzec infrastruktury: " & objInfraFsmo.fsmoroleowner

' Wzorzec nazw domen
set objDNFsmo = GetObject("LDAP://cn=Partitions," & strConfigDN)
Wscript.Echo "Wzorzec nazw domen: " & objDNFsmo.fsmoroleowner 
