' Kod wcza filtrowanie TCP/IP dla wszystkich kart i konfiguruje
' filtrowanie dla wszystkich kart korzystajcych z protokou IP.
' ------ KONFIGURACJA SKRYPTU ------
strComputer = "."
arrTCPPorts = Array ( 0 )       ' Udostpnianie wszystkich portw TCP
arrUDPPorts = Array ( 0 )       ' Udostpnianie wszystkich portw UDP
arrProtos   = Array ( 80, 25 )  ' Udostpnianie jedynie portw HTTP i SMTP
' ------ KONIEC KONFIGURACJI ---------
set objWMI = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
set objAdapterConfig = objWMI.Get("Win32_NetworkAdapterConfiguration")
intRC = objAdapterConfig.EnableIPFilterSec( True )
if intRC = 0 then
   WScript.Echo "Filtrowanie TCP/IP wczono dla wszystkich kart."
elseif intRC = 1 then
   WScript.Echo "Filtrowanie TCP/IP wczono dla wszystkich kart, " & _
                "ale w celu uwzgldnienia zmian konieczne jest przeadowanie systemu."
else
   WScript.Echo "Podczas wczania filtrowania TCP/IP dla wszystkich " & _
                "kart wystpi bd: " & intRC
end if

set colNAConfigs = objWMI.ExecQuery( _
                         "select * " & _
                         " from Win32_NetworkAdapterConfiguration " & _
                         " where IPEnabled = True" ) 
for each objNAConfig in colNAConfigs
   intRC = objNAConfig.EnableIPSec( arrTCPPorts, arrUDPPorts, arrProtos )
   if intRC = 0 then
      WScript.Echo "Filtrowanie TCP/IP skonfigurowano dla '" & _
                   objNAConfig.Description & "'"
   elseif intRC = 1 then
    WScript.Echo "Filtrowanie TCP/IP skonfigurowano dla '" & objNAConfig.Description & _
              "', ale w celu uwzgldnienia zmian konieczne jest przeadowanie systemu."
   else
      WScript.Echo "Podczas konfigurowania filtrowania TCP/IP dla '" & _
                   objNAConfig.Description & "wystpi bd: " & intRC
   end if
next
