' Kod planuje wykonanie zadania w kad niedziel o godzinie 1:30

const MON = 1
const TUE = 2
const WED = 4
const THU = 8
const FRI = 16
const SAT = 32
const SUN = 64

' ------ KONFIGURACJA SKRYPTU ------
strComputer  = "."
strCommand   = "c:\perl\bin\perl.exe c:\scripts\diskchecker.pl"
strStartTime = "********013000.000000-240"  ' 1:30 
               'RRRRMMDDGGMMSS.MMMMMM-/+TZO 
boolRepeat   = TRUE  ' Okresowe wykonywanie zadania
intWeekDay   = SUN   ' Wykonanie zadania w kad niedziel
intMonthDay  = ""    ' Po ustawieniu wartoci zadanie bdzie wykonywane co miesic
boolInteract = FALSE ' Brak interakcji z pulpitem
' ------ KONIEC KONFIGURACJI ---------
set objWMI = GetObject("winmgmts:\\" & strComputer & "")
set objNewTask = objWMI.Get("Win32_ScheduledJob")
intRC = objNewTask.Create(strCommand,   _
                          strstartTime, _
                          boolRepeat,   _
                          intWeekDay,   _
                          intMonthDay,  _
                          boolInteract, _
                          intJobID) 
if intRC <> 0 then
   Wscript.Echo "Podczas definiowania zadania wystpi bd: " & intRC
else
   WScript.Echo "Planowanie wykonania zadania zakoczono z powodzeniem."
   WScript.Echo "Identyfikator zadania: " & intJobID
end if
